ZFX + Developia

meiwen hat geschrieben:Da sich meine Z Achse aber auch weiter gedreht hat, liegen die Achsen nicht übereinander. Somit beschreiben zumindest in meiner Logik die Drehung um X und Z Achse nicht die gleiche Rotation.

meiwen hat geschrieben:In diesem Video dazu
https://www.youtube.com/watch?v=zc8b2Jo7mno
wird von einer Hierarchie der Achsen gesprochen.

Krishty hat geschrieben:Ich glaube, kimmi war es, der den Gimbal Lock mal sehr sehr anschaulich erklärt hat:

In einem Egoshooter kannst du nur furchtbar schwer zielen, wenn das Ziel senkrecht über oder unter dir liegt. Sobald du senkrecht nach unten guckst, und die Maus nach links oder rechts bewegst, drehst du dich nämlich nicht nur um deine globale Y-Achse, sondern auch um deine lokale Z-Achse. Das ist Gimbal Lock.

eXile hat geschrieben:Die Probleme am Nord- und Südpol liegen einfach an den Singularitäten der Parametrisierung.

Die Bilder sind mit Word

Bis jetzt ist mir noch nicht ganz klar, ob das einfach ignoriert wird oder ob es da grundlegende unterschiede zwischen den Parametrisierungen gibt.

• Ein Gimbal-Lock kann nur bei zwei bestimmten Stellungen des mittleren Winkels auftreten.
• Erste Gruppe: Gimbal-Lock tritt auf bei
  • \($\operatorname{XYZ}(\vartheta, 90^\circ, \psi), \operatorname{XYZ}(\vartheta, -90^\circ, \psi)$\)
  • \($\operatorname{XZY}(\vartheta, -90^\circ, \psi), \operatorname{XZY}(\vartheta, 90^\circ, \psi)$\)
  • \($\operatorname{YXZ}(\vartheta, -90^\circ, \psi), \operatorname{YXZ}(\vartheta, 90^\circ, \psi)$\)
  • \($\operatorname{YZX}(\vartheta, 90^\circ, \psi), \operatorname{YZX}(\vartheta, -90^\circ, \psi)$\)
  • \($\operatorname{ZXY}(\vartheta, 90^\circ, \psi), \operatorname{ZXY}(\vartheta, -90^\circ, \psi)$\)
  • \($\operatorname{ZYX}(\vartheta, -90^\circ, \psi), \operatorname{ZYX}(\vartheta, 90^\circ, \psi)$\)
• Zweite Gruppe: Gimbal-Lock tritt auf bei
  • \($\operatorname{XYX}(\vartheta, 0^\circ, \psi), \operatorname{XYX}(\vartheta, 180^\circ, \psi)$\)
  • \($\operatorname{XZX}(\vartheta, 0^\circ, \psi), \operatorname{XZX}(\vartheta, 180^\circ, \psi)$\)
  • \($\operatorname{YXY}(\vartheta, 0^\circ, \psi), \operatorname{XZX}(\vartheta, 180^\circ, \psi)$\)
  • \($\operatorname{YZY}(\vartheta, 0^\circ, \psi), \operatorname{XZX}(\vartheta, 180^\circ, \psi)$\)
  • \($\operatorname{ZXZ}(\vartheta, 0^\circ, \psi), \operatorname{XZX}(\vartheta, 180^\circ, \psi)$\)
  • \($\operatorname{ZYZ}(\vartheta, 0^\circ, \psi), \operatorname{XZX}(\vartheta, 180^\circ, \psi)$\)
• Es gibt positiven Gimbal-Lock: Beispielsweise \($\operatorname{XYZ}(x, 90^\circ, 0) = \operatorname{XYZ}(0, 90^\circ, x)$\)
• Und es gibt negativen Gimbal-Lock: Beispielsweise \($\operatorname{XYZ}(x, -90^\circ, 0) = \operatorname{XYZ}(0, -90^\circ, -x)$\)
• In obiger Liste entspricht der erste gegebene Wert für den mittleren Winkel immer einem positiven Gimbal Lock, der zweite Wert einem negativen Gimbal Lock

dot hat geschrieben:Genau das ist doch Gimbal Lock!? In 3D sind's eben Singularitäten der Parametrisierung einer Hypersphäre...

• Wir schauen ziemlich weit nach oben (\($m_y = 0.05$\)), und drehen uns einmal im Kreis (\($m_x \in [0,1]$\))
• x-Achse rot, y-Achse grün, z-Achse blau (wie gesagt: linkshändisches Koordinatensystem wie in Direct3D)
• Blickrichtung orange, zwei kleine Orthogonalvektoren grau

• Konvertiert man die von \($\operatorname{C_{FPS}}$\) zurückgegebenen Kugelkoordinaten in zweiter und dritter Komponente in euklidische Koordinaten, sehen wir, dass wir bereits zwei Singularitäten haben. Und zwar genau den von mir angesprochenen Nord- und Südpol.
• Da wir in der Abbildungskette nun bereits zwei Singularitäten haben, kriegen wir die durch spätere Abbildungen in der Kette auch nicht mehr weg. Es könnte aber noch theoretisch der Fall eintreten, dass auch genau an diesen Singularitäten von \($\operatorname{C_{FPS}}$\) ein Gimbal-Lock auftritt.
• Jedoch ist auch dies nicht der Fall: Wie wir obiger Auflistung der Gimbal-Lock-Winkel für \($\operatorname{XZY}$\) entnehmen können, träte der Gimbal-Lock bei \($\varphi = \mp 90^\circ$\) auf. D.h. in obiger Animation sind wir zweimal durch den Gimbal-Lock gelaufen, und es hat uns nicht gestört! Außerdem ist hier das Eintreten des Gimbal-Locks nicht vom Nord- oder Südpol abhängig, sondern von der Mausbewegung nach links/rechts! Es macht uns aber überhaupt keine Probleme, weil wir nicht Rollen wollen.

eXile hat geschrieben:Konvertiert man die von \($\operatorname{C_{FPS}}$\) zurückgegebenen Kugelkoordinaten in zweiter und dritter Komponente in euklidische Koordinaten, sehen wir, dass wir bereits zwei Singularitäten haben. Und zwar genau den von mir angesprochenen Nord- und Südpol.

Bei einer Eulersequenz verliert der dritte Winkel seine Bedeutung ⇔ Gimbal Lock
Bei Kugelkoordinaten verliert der Azimut im Zenit bzw. Nadir seine Bedeutung ⇔ Gimbal Lock

dot hat geschrieben:Wobei ich nochmal drüber nachgedacht hab und mich vor eXiles ausführlicher Argumentation respektvoll verneigen muss ;). Die den Kugelkoordinaten entsprechenden kartesischen Koordinaten haben dort eine Singularität, die XY Sequenz aber nicht. Bei dem Beispiel mit der FPS Kamera handelt es sich tatsächlich nicht um Gimbal Lock. Ich hab den selben Fehler gemacht wie die Wikipedia...

Alexander Kornrumpf hat geschrieben:Der Wikipedia Artikel ist falsch (Wenn man Gimbal Lock als das Align mehrerer Gimbalachsen definiert).

dot hat geschrieben:

Alexander Kornrumpf hat geschrieben:Der Wikipedia Artikel ist falsch (Wenn man Gimbal Lock als das Align mehrerer Gimbalachsen definiert).

Korrekt, allerdings ist Gimbal Lock eben nicht als das Align mehrer Achsen definiert, sondern als der Verlust eines Freiheitsgrades, der bei Eulerwinkeln allerdings eben genau dann auftritt, wenn Achsen alignen. Beim Teleskopbeispiel geht genauso ein Freiheitsgrad verloren...

dot hat geschrieben:Im Zenit und Nadar hat das Teleskop aber eben nurmehr einen Freiheitsgrad, oder täusch ich mich da?

Alexander Kornrumpf hat geschrieben:Im Zenit kannst du es um die "eigene Achse" drehen. Das ändert die Orientierung des Dings schon. Aber nicht wo du hinschaust wenn du durchschaust. Bei einem asymmetrischen Gegenstand wäre das aber ein echter Freiheitsgrad. Und darum geht es doch.

Jonathan hat geschrieben:Ihr seid cool Jungs! Wissenschaft live :D

• Die Kameraparametrisierung wird in jedem Fall Singularitäten am Nord- und Südpol erzeugen
• Bei allen für FPS-Kameras verwendbaren Euler-Winkel-Notationen mit Ausnahme einer einzigen wird in diesen Singularitäten kein Gimbal-Lock angenommen
• Es gibt jedoch genau eine Euler-Winkel-Notation, wo genau am Nord- und Südpol und nur dort ein Gimbal-Lock einsteht:
  • Nämlich bei \($\operatorname{YZX}$\)
  • Immer vorausgesetzt man benutzt ein Direct3D-Koordinatensystem

• Wenn man nicht Rollen will, ist sie so gut wie jede andere Euler-Winkel-Notation
• Wenn man Rollen will, dann erzeugt der Gimbal-Lock ein "intuitives" Verhalten:
  • Schaut man nicht zum Nord- oder Südpol, rollt man ganz normal
  • Schaut man zum Nord- oder Südpol, kriegt man, wenn man rollt, den gleichen Effekt, als ob man die Maus nach links/rechts bewegen würde :)

Rx[\[Theta]_] = RotationMatrix[\[Theta], {1, 0, 0}]

Ry[\[Theta]_] = RotationMatrix[\[Theta], {0, 1, 0}]

Rz[\[Theta]_] = RotationMatrix[\[Theta], {0, 0, 1}]

(* Generate all Euler notations *)
R1[\[Theta]_, \[Phi]_, \[Psi]_] = 
  Simplify[Rx[\[Theta]].Ry[\[Phi]].Rz[\[Psi]]];
R2[\[Theta]_, \[Phi]_, \[Psi]_] = 
  Simplify[Rx[\[Theta]].Rz[\[Phi]].Ry[\[Psi]]];
R3[\[Theta]_, \[Phi]_, \[Psi]_] = 
  Simplify[Ry[\[Theta]].Rx[\[Phi]].Rz[\[Psi]]];
R4[\[Theta]_, \[Phi]_, \[Psi]_] = 
  Simplify[Ry[\[Theta]].Rz[\[Phi]].Rx[\[Psi]]];
R5[\[Theta]_, \[Phi]_, \[Psi]_] = 
  Simplify[Rz[\[Theta]].Rx[\[Phi]].Ry[\[Psi]]];
R6[\[Theta]_, \[Phi]_, \[Psi]_] = 
  Simplify[Rz[\[Theta]].Ry[\[Phi]].Rx[\[Psi]]];
R7[\[Theta]_, \[Phi]_, \[Psi]_] = 
  Simplify[Rx[\[Theta]].Ry[\[Phi]].Rx[\[Psi]]];
R8[\[Theta]_, \[Phi]_, \[Psi]_] = 
  Simplify[Rx[\[Theta]].Rz[\[Phi]].Rx[\[Psi]]];
R9[\[Theta]_, \[Phi]_, \[Psi]_] = 
  Simplify[Ry[\[Theta]].Rx[\[Phi]].Ry[\[Psi]]];
R10[\[Theta]_, \[Phi]_, \[Psi]_] = 
  Simplify[Ry[\[Theta]].Rz[\[Phi]].Ry[\[Psi]]];
R11[\[Theta]_, \[Phi]_, \[Psi]_] = 
  Simplify[Rz[\[Theta]].Rx[\[Phi]].Rz[\[Psi]]];
R12[\[Theta]_, \[Phi]_, \[Psi]_] = 
  Simplify[Rz[\[Theta]].Ry[\[Phi]].Rz[\[Psi]]];

(* In these angles we will have a gimbal lock - visible because of \
the addition of angles in the resulting matrix *)
Simplify[R1[\[Theta], 90 Degree, \[Psi]]]
Simplify[R2[\[Theta], -90 Degree, \[Psi]]]
Simplify[R3[\[Theta], -90 Degree, \[Psi]]]
Simplify[R4[\[Theta], 90 Degree, \[Psi]]]
Simplify[R5[\[Theta], 90 Degree, \[Psi]]]
Simplify[R6[\[Theta], -90 Degree, \[Psi]]]
Simplify[R7[\[Theta], 0 Degree, \[Psi]]]
Simplify[R8[\[Theta], 0 Degree, \[Psi]]]
Simplify[R9[\[Theta], 0 Degree, \[Psi]]]
Simplify[R10[\[Theta], 0 Degree, \[Psi]]]
Simplify[R11[\[Theta], 0 Degree, \[Psi]]]
Simplify[R12[\[Theta], 0 Degree, \[Psi]]]

(* We want to use a left-handed coordinate system, like in Direct3D. \
Invert some axis. Here, we invert the z-Axis. *)
InvertZ[x_] := {x[[1]], x[[2]], -x[[3]]};

(* Use a simpe mouse to Euler-angle transformation for R2 *)
MouseToAngle[mx_, my_] = {Pi/2, 
   Mod[2 Pi*mx + Pi/2 , 2 Pi], -Pi*my + Pi/2};

(* Play with R2: Use \[Phi] and \[Psi] *)
Manipulate[Graphics3D[{Thick,
   Red, Line[{{0, 0, 0}, InvertZ [{1, 0, 0}]}],
   Green, Line[{{0, 0, 0}, InvertZ[{0, 1, 0}]}],
   Blue, Line[{{0, 0, 0}, InvertZ[{0, 0, 1}]}],
   Orange, 
   Line[{{0, 0, 0}, InvertZ[R2[\[Theta], \[Phi], \[Psi]].{1, 0, 0}]}],
   Gray, Line[{{0, 0, 0}, 
     InvertZ[R2[\[Theta], \[Phi], \[Psi]].{0, 0.5, 0}]}],
   Gray, Line[{{0, 0, 0}, 
     InvertZ[R2[\[Theta], \[Phi], \[Psi]].{0, 0, 0.5}]}]},
  {PlotRange -> {{-1, 1}, {-1, 1}, {-1, 1}}, 
   ViewVertical -> {0, 1, 0}, ViewPoint -> {1.5, 2, 1}}], {{\[Theta], 
   90 Degree}, 0, 2 Pi}, {\[Phi], 0, 2 Pi}, {{\[Psi], 100 Degree}, 0, 
  2 Pi}]

(* Play with R2: Use mx and my *)
Manipulate[Graphics3D[{Thick,
   Red, Line[{{0, 0, 0}, InvertZ [{1, 0, 0}]}],
   Green, Line[{{0, 0, 0}, InvertZ[{0, 1, 0}]}],
   Blue, Line[{{0, 0, 0}, InvertZ[{0, 0, 1}]}],
   Orange, 
   Line[{{0, 0, 0}, InvertZ[R2 @@ MouseToAngle[mx, my].{1, 0, 0}]}],
   Gray, Line[{{0, 0, 0}, 
     InvertZ[R2 @@ MouseToAngle[mx, my].{0, 0.5, 0}]}],
   Gray, Line[{{0, 0, 0}, 
     InvertZ[R2 @@ MouseToAngle[mx, my].{0, 0, 0.5}]}]},
  {PlotRange -> {{-1, 1}, {-1, 1}, {-1, 1}}, 
   ViewVertical -> {0, 1, 0}, ViewPoint -> {1.5, 2, 1}}],
 {mx, 0, 1}, {my, 0, 1}]

(* Plot the R2 rotation animation *)
rotationAnimation = Table[Graphics3D[{Thick,
     Red, Line[{{0, 0, 0}, InvertZ [{1, 0, 0}]}],
     Green, Line[{{0, 0, 0}, InvertZ[{0, 1, 0}]}],
     Blue, Line[{{0, 0, 0}, InvertZ[{0, 0, 1}]}],
     Orange, 
     Line[{{0, 0, 0}, 
       InvertZ[R2 @@ MouseToAngle[mx, 0.05].{1, 0, 0}]}],
     Gray, 
     Line[{{0, 0, 0}, 
       InvertZ[R2 @@ MouseToAngle[mx, 0.05].{0, 0.5, 0}]}],
     Gray, 
     Line[{{0, 0, 0}, 
       InvertZ[R2 @@ MouseToAngle[mx, 0.05].{0, 0, 0.5}]}]},
    {PlotRange -> {{-1, 1}, {-1, 1}, {-1, 1}}, 
     ViewVertical -> {0, 1, 0}, ViewPoint -> {1.5, 2, 1}}],
   {mx, 0, 1, 0.025}];

(* Safe the animation as a GIF *)
Export["animation.gif", rotationAnimation, "DisplayDurations" -> 0.01]

Rotation um den Nordpol:

R1: 	theta=0		phi=[0, 2Pi]	psi=90
	-		var		eps		1 Lösung

R2:	theta=90	phi=[0, 2Pi]	psi=90
	-		var		eps		1 Lösung

R3:	theta=[0, 2Pi]	phi=0		psi=90
	var		eps		eps		2 Lösungen

R4:	theta=[0, 2Pi]	phi=90		psi=0		
	var		eps		-		1 Lösung, Gimbal Lock

R5:	theta=90	phi=[0, 2Pi]	psi=0
	-		var		eps		1 Lösung

R6:							Keine einparametrische Lösung
	-		-		var		0 Lösungen



R7:							Keine einparametrische Lösung
	-		-		var		0 Lösungen

R8:							Keine einparametrische Lösung
	-		-		var		0 Lösungen

R9:	theta=[0, 2Pi]	phi=90		psi=90
	var		eps		eps		2 Lösungen

R10:	theta=[0, 2Pi]	phi=90		psi=0
	var		eps		eps		2 Lösungen

R11:	theta=90	phi=[0, 2Pi]	psi=0
	-		var		eps		1 Lösung

R12:	theta=0		phi=[0, 2Pi]	psi=90		
	-		var		eps		1 Lösung



3x 0 Lösungen
6x 1 Lösung (5x ohne, 1x mit Gimbal Lock)
3x 2 Lösungen