ZFX + Developia

Code: Alles auswählen

{
	"Name" : "RenderTexture",
	"Shaders" : {
		 "Pixel" : "RenderTexturePS",
		 "Vertex" : "RenderTextureVS"
	},
	"Samplers" : [
		{
		"Name" : "pointSampler",
		"Filter" : "Point"
		}
	]
}

Code: Alles auswählen

// Basiseffekt Transform.fx, definiert einfache Transformation
struct TransformHookState
{
	float4 WorldPos;
	float3 WorldNormal;
	float4 WVPPos;
};

float4 GetWorldPosition(TransformHookState s) { return s.WorldPos; }
float4 GetWVPPosition(TransformHookState s) { return s.WVPPos; }
float3 GetWorldNormal(TransformHookState s) { return s.WorldNormal; }

// _HOOKED ist gesetzt, wenn dieser Effect als Hook eingebunden wurde (im Gegensatz zu Standard-#include)
#ifdef _HOOKED

// Konfiguriere Headers zum Einbinden der richtigen Matrizen (World, WorldInverse, WorldViewProj)
#hookconfig
{
	#redefine BE_RENDERABLE_INCLUDE_WORLD
	#redefine BE_RENDERABLE_INCLUDE_PROJ
}

#include <Engine/Perspective.fx>
#include <Engine/Renderable.fx>

TransformHookState DefaultTransformHook(float4 pos, float3 normal)
{
	TransformHookState state;
	state.WorldPos = mul(pos, World);
	state.WorldNormal = normalize( mul((float3x3) WorldInverse, normal) );
	state.WVPPos = mul(pos, WorldViewProj);
	return state;
}

// Definiere virtuelle Hook-Funktion "Transform" mit Zustandstyp TransformHookState,
// kann in abgeleitetem Effekt per '#hookcall Transform(vertex)' aufgerufen werden
#hookfun Transform(vertex) -> TransformHookState = DefaultTransformHook(vertex.Position, vertex.Normal)

#endif

Code: Alles auswählen

// Prozedurale Windanimation

// Definiert zusätzliche Konstanten zur Steuerung der Windanimation,
// können in abgeleitetem Effekt per '#hookinsert SetupConstants' eingebunden werden
#hookdef SetupConstants
{
	float AnchorHeight
	<
		String UIName = "Anchor Height";
	> = 10.0f;

	float FreeHeight
	<
		String UIName = "Free Height";
	> = 0.0f;

	float3 Amplitude
	<
		String UIName = "Amplitude";
	> = 0.0f;
}

// Konfiguriere Headers zum Einbinden der richtigen Matrizen (World, WorldInverse, WorldViewProj)
#hookconfig
{
	#redefine BE_RENDERABLE_INCLUDE_WORLD
	#redefine BE_RENDERABLE_INCLUDE_PROJ
}

#include <Engine/Perspective.fx>
#include <Engine/Renderable.fx>

// Bindet nur den nicht-_HOOKED-Teil ein, um die dort definierten Strukturen/Funktionen wiederzuverwenden
#include <Hooks/Transform.fx>

[...]

// '#hookstate Transform' liefert dynamisch gebundenen Zustandstyp der Transform-Hook-Implementierung des Basis-Effects
TransformHookState WindTransform(#hookstate Transform baseState)
{
	TransformHookState state;

	float4 basePos = GetWorldPosition(baseState);
	float3 baseNormal = GetWorldNormal(baseState);

	state.WorldPos = float4(WindPerturbWorldPosition(basePos.xyz), basePos.w);
	state.WorldNormal = normalize( WindPerturbWorldNormal(baseNormal, basePos.y) );

	state.WVPPos = mul(state.WorldPos, Perspective.ViewProj);

	return state;
}

// Überschreibt virtuelle Hook-Funktion "Transform" mit Zustandstyp TransformHookState,
// ruft Basis-Effect mit #hookcall Transform(vertex) auf,
// kann in abgeleitetem Effekt per '#hookcall Transform(vertex)' aufgerufen werden
#hookfun Transform(vertex) -> TransformHookState = WindTransform(#hookcall Transform(vertex))

Code: Alles auswählen

// Normaler Material-Effect, der nun mit beliebigen Hooks manipuliert werden kann
#include <Engine/Perspective.fx>
#include <Engine/Renderable.fx>
#include <Pipelines/LPR/Geometry.fx>

// Bindet IMMER "Transform.fx" als Basiseffekt ein, um auch ohne zusätzliche Hooks Standard-Funktionalität zu haben
#hookincl "Hooks/Transform.fx"
// Bindet beliebig viele weitere, zur Compile-Zeit gegebene Hook-Effect-Files ein, in unserem Beispiel "Wind.fx"
#hookincl ...

cbuffer SetupConstants
{
	float4 DiffuseColor
	<
		String UIName = "Diffuse";
		String UIWidget = "Color";
	> = float4(1.0f, 1.0f, 1.0f, 0.0f);

	float4 SpecularColor
	<
		String UIName = "Specular";
		String UIWidget = "Color";
	> = float4(0.0f, 0.0f, 0.0f, 0.1f);

	float2 TextureRepeat
	<
		String UIName = "Texture Repeat";
	> = float2(1.0f, 1.0f);

	// Fügt nacheinander alle per '#hookdef SetupConstants' definierten Bereiche ein, in diesem Beispiel den aus "Wind.fx",
	// so landen in diesem Constant Buffer auch alle Wind-Konstanten
	#hookinsert SetupConstants
}

[...]

Pixel VSMain(Vertex v)
{
	// Ruft zuletzt definierte Hook-Funktion auf, in diesem Beispiel die aus "Wind.fx", und speichert deren
	// Zustand in 'transformState' (Kurzschreibweise für: '#hookstate Transform transformState = #hookcall Transform(v)')
	// Transform() in "Wind.fx" gibt dann teilweise weiter an überschriebenen Hook aus "Transform.fx", siehe oben
	#hookcall transformState = Transform(v);

	Pixel o;
	o.Position = GetWVPPosition(transformState);
	[...]
	return o;
}

[...]

// Teile Standardfunktionalität mit anderen Effects (= binde vorkompilierte Effects ein)
technique11 <
	string IncludeEffect = "Prototypes/Shadow.fx";
	// Präprozessor liefert Array mit zur Compilezeit angegebenen Hook Files, i.d.Bsp. { "Wind.fx" }
	string IncludeHooks[] = #hookarray;
> { }

Code: Alles auswählen

#define _HOOKED

#ifndef BE_RENDERABLE_INCLUDE_WORLD
#define BE_RENDERABLE_INCLUDE_WORLD
#endif
#ifndef BE_RENDERABLE_INCLUDE_PROJ
#define BE_RENDERABLE_INCLUDE_PROJ
#endif

#undef _HOOKED
#include <Engine/Perspective.fx>
#define _HOOKED
#undef _HOOKED
#include <Engine/Renderable.fx>
#define _HOOKED
#undef _HOOKED
#include <Pipelines/LPR/Geometry.fx>
#define _HOOKED

#ifndef BE_HOOK_TRANSFORM
#define BE_HOOK_TRANSFORM

struct TransformHookState
{
	float4 WorldPos;
	float3 WorldNormal;
	float4 WVPPos;
};

float4 GetWorldPosition(TransformHookState s) { return s.WorldPos; }
float4 GetWVPPosition(TransformHookState s) { return s.WVPPos; }
float3 GetWorldNormal(TransformHookState s) { return s.WorldNormal; }

#ifdef _HOOKED

#undef _HOOKED
#include <Engine/Perspective.fx>
#define _HOOKED
#undef _HOOKED
#include <Engine/Renderable.fx>
#define _HOOKED

TransformHookState DefaultTransformHook(float4 pos, float3 normal)
{
	TransformHookState state;
	state.WorldPos = mul(pos, World);
	state.WorldNormal = normalize( mul((float3x3) WorldInverse, normal) );
	state.WVPPos = mul(pos, WorldViewProj);
	return state;
}

#define Transform__HOOKFUN1(vertex) DefaultTransformHook(vertex.Position, vertex.Normal)

#endif

#endif


#undef _HOOKED
#include <Engine/Perspective.fx>
#define _HOOKED
#undef _HOOKED
#include <Engine/Renderable.fx>
#define _HOOKED

#undef _HOOKED
#include <Hooks/Transform.fx>
#define _HOOKED

[...]

TransformHookState WindTransform(TransformHookState baseState)
{
	TransformHookState state;

	float4 basePos = GetWorldPosition(baseState);
	float3 baseNormal = GetWorldNormal(baseState);

	state.WorldPos = float4(WindPerturbWorldPosition(basePos.xyz), basePos.w);
	state.WorldNormal = normalize( WindPerturbWorldNormal(baseNormal, basePos.y) );

	state.WVPPos = mul(state.WorldPos, Perspective.ViewProj);

	return state;
}

#define Transform__HOOKFUN2(vertex) WindTransform(Transform__HOOKFUN1(vertex))


cbuffer SetupConstants
{
	float4 DiffuseColor
	<
		String UIName = "Diffuse";
		String UIWidget = "Color";
	> = float4(1.0f, 1.0f, 1.0f, 0.0f);

	float4 SpecularColor
	<
		String UIName = "Specular";
		String UIWidget = "Color";
	> = float4(0.0f, 0.0f, 0.0f, 0.1f);

	float2 TextureRepeat
	<
		String UIName = "Texture Repeat";
	> = float2(1.0f, 1.0f);

	float AnchorHeight
	<
		String UIName = "Anchor Height";
	> = 10.0f;

	float FreeHeight
	<
		String UIName = "Free Height";
	> = 0.0f;

	float3 Amplitude
	<
		String UIName = "Amplitude";
	> = 0.0f;
}

[...]

Pixel VSMain(Vertex v)
{
	Pixel o;
	
	TransformHookState transformState = Transform__HOOKFUN2(v);

	o.Position = GetWVPPosition(transformState);
	o.NormalDepth.xyz = GetWorldNormal(transformState);
	o.NormalDepth.w = o.Position.w;
	o.TexCoord = v.TexCoord * TextureRepeat;

	IF_NORMALMAP(
		o.Tangent.xyz = mul(v.Tangent, (float3x3) World);
		// Extract handedness
		o.Tangent.w = sign(dot(v.Tangent, v.Tangent) - 0.5f);
	)

	IF_OBJECTNORMAL(
		o.ObjectNormal = normalize( mul((float3x3) WorldInverse, v.ObjectNormal) );
	)
	
	return o;
}

[...]

technique11 Geometry <
	string PipelineStage = "GeometryPipelineStage";
	string RenderQueue = "DefaultRenderQueue";
>
{
	pass
	{
		SetVertexShader( CompileShader(vs_4_0, VSMain()) );
		SetGeometryShader( NULL );
		SetPixelShader( CompileShader(ps_4_0, PSGeometry()) );
	}
}

technique11 <
	string IncludeEffect = "Prototypes/Shadow.fx";
	string IncludeHooks[] = { "Modifiers/Wind.fx" };
> { }

technique11 <
	string IncludeEffect = "Prototypes/Feedback.fx";
	string IncludeHooks[] = { "Modifiers/Wind.fx" };
> { }